Getting Started With ESP-NOW in the Arduino IDE

    #include <esp_now.h>
#include <WiFi.h>

// MAC Address of the responder (Broadcast Address: {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF})
uint8_t receiverAddress[] = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF};

// Structure example to send data
// Must match the receiver structure
typedef struct struct_message {
  bool enable;
} struct_message;

struct_message myData;

esp_now_peer_info_t peerInfo;

const int buttonPin = 33;

// callback when data is sent
void OnDataSent(const uint8_t *mac_addr, esp_now_send_status_t status) {
  Serial.print("\r\nLast Packet Send Status:\t");
  Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
}
 
void setup() {
  // Init button port
  pinMode(buttonPin, INPUT_PULLUP);

  // Init Serial Monitor
  Serial.begin(115200);
 
  // Set device as a Wi-Fi Station
  WiFi.mode(WIFI_STA);

  // Init ESP-NOW
  if (esp_now_init() != ESP_OK) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }

  // Once ESPNow is successfully initialized, we will register the callback function to
  // get the status of Trasnmitted packet
  esp_now_register_send_cb(OnDataSent);
  
  // Register peer
  memcpy(peerInfo.peer_addr, receiverAddress, 6);
  peerInfo.channel = 0;  
  peerInfo.encrypt = false;
  
  // Add peer (pair device)
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
}

void loop() {
  // Read button input
  if (digitalRead(buttonPin) == HIGH) {
    // Set value to send
    myData.enable = !myData.enable;

    // Send message via ESP-NOW
    esp_err_t result = esp_now_send(receiverAddress, (uint8_t *) &myData, sizeof(myData));

    // Wait until button is released
    while (digitalRead(buttonPin) == HIGH);
    delay(500);
  }
}